C$Procedure                         SUNORB
C
      SUBROUTINE SUNORB ( DATE , SUN )
C
C*******************************************************************************
C
C       Copyright (C) 1993, California Institute of Technology.  U.S.
C       Government Sponsorhip under NASA Contract NAS7-918 is
C       acknowledged.
C
C*******************************************************************************
C
C
C$ Purpose
C
C  SUNORB computes the mean orbital elements of the Sun in EME and equinox
C  of date coordinate system.
C
C$ Input_Arguments
C
C  DATE   - epoch at which to determine orbital elements of Sun
C
C$ Output_Arguments
C
C  SUN    - mean orbital elements of the Sun (a,e,i,LAN,w,M), km,deg
C
C$ Log
C
C  21-Mar-1989 - Eric Cannell     - creation
C
C$ Library_Links
C
C  TIMETRANS
C
C$ Parameters
C
      CHARACTER*25         J1899
      PARAMETER          ( J1899 = '31-DEC-1899 12:00:00.0000' )
C
C$ Declarations_of_Input_and_Output_Arguments
C
      CHARACTER*(*)        DATE
      DOUBLE PRECISION     SUN    ( 6 )
C
C$ Declarations_of_Local_Variables
C
      DOUBLE PRECISION     D
      DOUBLE PRECISION     DF
      LOGICAL              ERROR
      DOUBLE PRECISION     JD1899
      DOUBLE PRECISION     JDEPOC
C           
C$ External_Statements
C
      DOUBLE PRECISION     CH2JD
      EXTERNAL             CH2JD
C
C$ Method
C-&

C1    Convert reference epoch and orbit epoch to Julian date.

      JD1899 = CH2JD ( J1899 , .TRUE. , ERROR )
      JDEPOC = CH2JD ( DATE  , .TRUE. , ERROR )

C1    Compute number of ephemeris days from reference epoch and fraction.

      D  = JDEPOC - JD1899
      DF = D / 10000.0D0

C1    Compute orbital elements of Sun (a, e, i, LAN , w, M).

      SUN( 1 ) = 149 600 000.0D0
      SUN( 2 ) = 0.01675104D0 - 0.000011444D0*DF - 9.4D-9*DF**2
      SUN( 3 ) = 23.452294D0 - 3.5626D-3*DF - 1.23D-7*DF**2 + 
     &           1.03D-8*DF**3
      SUN( 4 ) = 0.0D0
      SUN( 5 ) = 281.220844D0 + 4.70684D-5*D + 3.39D-5*DF**2 + 
     &           7.D-8*DF**3
      SUN( 6 ) = 358.475833D0 + .9856002670D0*D - 1.12D-5*DF**2 - 
     &           7.D-8*DF**3 

      SUN( 6 ) = DMOD( SUN( 6 ) , 360.0D0 )

      RETURN
      END